** www.staff.stir.ac.uk/paul.lambert .
** This file is for personal info only. 

******************************************************.
******************************************************.
****** SPSS 


** Path definitions .
define !path1 () 'c:\research\max\cult\data05\v2\' !enddefine. 
define !path9 () 'c:\temp\' !enddefine. 
get file=!path9+"mtch1.sav".


** Macro definitions .
define isegp1 ( occ=!tokens(1)
      /egp10=!tokens(1)  /empst=!tokens(1)   /supvr=!tokens(1)  ).
* [snip] .
!enddefine.
define isegp2 ( occ=!enclose('{','}').
* [snip] .
!enddefine.

isegp1 occ=isco egp10=egpv1 empst=ukempst supvr=supervis . 
isegp2 occ={hocc wocc pocc}.

** Factor :.
include file="c:\stats\soft\spss\macros\categ-macs.sps".
fre var=marstat. 
factor marstat mst 7 .

** Transfer value labels :.
include file="c:\stats\soft\spss\macros\varlabstonew.sps" .
compute mar2=marstat.
!applab marstat tovars mar2 .
fre var=marstat mar2.


** Define regression models :.
include file="c:\stats\soft\spss\macros\regressions.sps".
regres1 dep=workhrs expl={female age age2} . 
regres3 dep=wk30p expl={female age age2}. 


** SPSS Tables commands :.
tables /format blank missing ('.') /ftotal=ftot1 "Total"
  /tables (labels) + ftot1 by empst >  (hocc2 + wocc2) 
  /statistics count ((F5.0) ' Cases '). 


** SPSS multiple response data :.
* MR groups :.
mult response groups=imprv (impnhs1 impnhs2 (1,9)) 
           /frequencies=imprv. 
mult response groups=imprv (impnhs1 impnhs2 (1,9)) 
            /variables=rsex(1,2)  /tables=imprv by rsex. 
tables /format blank missing ('.') /ftotal=ftot1 "Total" ftot2 "All"  
    /mrgroup=mrvar " " impnhs1 impnhs2      /tables  mrvar + ftot1 
  /statistics count ((F5.0) ' ') cpct (mrvar (pct3.1) ' ' )
   /title= "Scottish Social Attitudes 2002:" "Improvements wanted for health service (multiple responses)"    .
tables /format blank missing ('.') /ftotal=ftot1 "Total" ftot2 "All"  
    /mrgroup=mrvar " " impnhs1 impnhs2      /tables  mrvar + ftot1 by  rsex + ftot2 
  /statistics count ((F5.0) ' ') cpct (mrvar (pct3.1) ' ':rsex)
   /title= "Scottish Social Attitudes 2002:" "Improvements wanted for health service (multiple responses), by gender"    .
* MR dichotomies. 
mult response groups=travel(j1sch j1work j1shops j1leis j1famfr j1pleas (1) )
      /fre=travel . 
compute j1notrv=max(j1sch, j1work, j1shops, j1leis, j1famfr, j1pleas).
recode j1notrv (1=0) (0=1).
variable label j1notrv "Doesn't use car for any of above".
mult response groups=travel2(j1sch j1work j1shops j1leis j1famfr j1pleas j1notrv (1) )
      /fre=travel2 . 
mult response groups=educ(edqual1 to edqual16 (1) )
      /fre=educ . 
tables /format blank missing ('.') /ftotal=ftot1 "Total" ftot2 "All"  
    /mdgroup=mdvar " " j1sch j1work j1shops j1leis j1famfr j1pleas j1notrv (1)
     /tables  mdvar + ftot1 by  rsex > urbanac  
  /statistics count ((F5.0) ' ') cpct (mdvar (pct3.1) ' ':rsex,urbanac)
   /title= "Scottish Social Attitudes:" "Use of car for travelling (multiple response), by gender and location"   .



** SPSS CA :.
anacor table=hocc2 (1,324) by wocc2(1,324)
  /normalisation=canonical /print=scores.
correspondence table=hocc2 (1,324) by wocc2 (1,324) 
  /dimensions=2 /measure=chisq 
  /standardize=rcmean /normalization=symmetrical
  /print=table rpoint cpoint  /plot=ndim(1,max) biplot(20).


******************************************************.
******************************************************.







******************************************************.
******************************************************.
******** STATA 

global path1 "c:\psl\cult\data05\" 
global path9 "c:\temp\" 
use $path9\mtch1.dta, clear 



** labels : 

tab femp mune 
label variable femp "Wife's employment status" 
label variable mune "Husband's employment status" 

label define fempl 0 "Unemployed" 1 "Employed" 
label define munel 0 "Employed" 1 "Unemployed" 
label values femp fempl 
label values mune munel 
numlabel _all, add
tab femp mune



******************************************************.
******************************************************.







******************************************************.

** Copy: Regressions.sps :.


*****************************************.
* 1) Linear Multiple regression :.


define regres1 (dep=!tokens(1) /expl=!enclose('{','}')) .
descriptives var=!dep !expl. 
correlate var=!dep !expl. 
regression / statistics coeff outs r anova collin tol
   /criteria = pin(0.05) pout(0.10) /noorigin
   /dependent=!dep   /method=enter !expl  
  /residuals durbin histogram(zresid) /casewise plot(zresid) outliers(3) /scatterplot (!dep *pred) (*zresid *zpred)  .
!enddefine. 


******************************************.
* 2) Ordered conditional logit (plum logit).


define regres2 (dep=!tokens(1) /expl=!enclose('{','}')) .
fre var=!dep.
descriptives var=!dep !expl. 
correlate var=!dep !expl. 
plum !dep with !expl 
  /criteria = cin(95) delta(0) mxiter(100) mxstep(5) lconverge(0)
  pconverge(1.0E-6) singular(1.0E-8)
  /link = logit   /print = fit parameter summary .
!enddefine. 


***********************************************************.
* 3) Logistic regression .


define regres3 (dep=!tokens(1) /expl=!enclose('{','}')) .
fre var=!dep.
descriptives var=!dep !expl. 
correlate var=!dep !expl. 
logistic regression var= !dep  
       /method=enter !expl      /criteria pin(.05) pout(.10) iterate (20) cut (.5).
!enddefine. 


*********************************************************.
* 4) Multinomial logit regression :.

define regres4 (dep=!tokens(1) /expl=!enclose('{','}')) .
fre var=!dep.
descriptives var=!dep !expl. 
correlate var=!dep !expl. 
nomreg !dep  with  !expl
 /criteria = cin(95) delta(0) mxiter(100) mxstep(5) lconverge(0)
  pconverge(1.0E-6) singular(1.0E-8)
  /model  /intercept = include
  /print= parameter summary lrt.
!enddefine. 



**************************************************************.
* 5) 2-level Variance components, predicts dep with expl given clust. 


define regres5 (dep=!tokens(1) /expl=!enclose('{','}') /clust=!tokens(1)) .
descriptives var=!clust !dep !expl. 
correlate var=!dep !expl. 
means tables=!dep by !clust. 
mixed !dep with !expl 
         /criteria=cin(95) mxiter(100) mxstep(5) scoring(1) singular(0.000000000001) 
         hconverge(0,absolute) lconverge(0,absolute) pconverge(0.000001, absolute)
          /fixed=!expl  | sstype(3)
         /method=reml 
         /print=corb solution  r
          /random=intercept | subject(!clust) covtype(ID)   .
!enddefine. 



**************************************************************.
* 6) Multivariate model, predicts several dep with expl . 


define regres6 (dep=!enclose('{','}') /expl=!enclose('{','}')  ) .
descriptives var= !dep !expl. 
correlate var=!dep .
correlate var=!dep !expl. 
glm !dep with !expl
  /method=sstype(3) /intercept=include /print=descriptive etasq opower parameter test(sscp) rsscp test(mmatrix) lof gef
  /plot=residuals  /criteria=alpha(0.05) 
  /design=!expl .


!enddefine. 







****************************************.
** Selected explantory variable algorithms :.

* 1b) Linear Multiple regression, stepwise entry  :.

define reg1s (dep=!tokens(1) /expl=!enclose('{','}')) .
descriptives var=!dep !expl. 
correlate var=!dep !expl. 
regression / statistics coeff outs r anova collin tol
   /criteria = pin(0.05) pout(0.10) /noorigin
   /dependent=!dep   /method=stepwise !expl  
  /residuals durbin histogram(zresid) /casewise plot(zresid) outliers(3) /scatterplot (!dep *pred) (*zresid *zpred)  .
!enddefine.


* 1c) Linear Multiple regression, backward elimination  :.

define reg1s (dep=!tokens(1) /expl=!enclose('{','}')) .
descriptives var=!dep !expl. 
correlate var=!dep !expl. 
regression / statistics coeff outs r anova collin tol
   /criteria = pin(0.05) pout(0.10) /noorigin
   /dependent=!dep   /method=backward !expl  
  /residuals durbin histogram(zresid) /casewise plot(zresid) outliers(3) /scatterplot (!dep *pred) (*zresid *zpred)  .
!enddefine.



* 1d) Linear Multiple regression, forward elimination  :.

define reg1s (dep=!tokens(1) /expl=!enclose('{','}')) .
descriptives var=!dep !expl. 
correlate var=!dep !expl. 
regression / statistics coeff outs r anova collin tol
   /criteria = pin(0.05) pout(0.10) /noorigin
   /dependent=!dep   /method=forward !expl  
  /residuals durbin histogram(zresid) /casewise plot(zresid) outliers(3) /scatterplot (!dep *pred) (*zresid *zpred)  .
!enddefine.



********************************************************.
*******************************************************.